Diagramming with Delphi Part 2, The Adventure Continues

By Jim Cooper (jcooper@tabdee.ltd.uk)

Well, folks, here we are again, ready for the fray. As promised last month, this time we will be making our diagramming components movable and sizeable, and we will also be able to store entire diagrams in a file. To demonstrate these new capabilities, we will create a basic use case editor. We will very briefly discuss what exactly a use case is, and why we should be using them. To refresh your memory, or if you missed last month’s issue (shame on you, back issues are still available, I’m sure), we defined diagrams as “a set of nodes, optionally joined by some sort of connector”. Actually, in a use case diagram, all nodes will be joined to at least one other.

The Deep End

Remember that last time, we inherited all our diagramming classes from the base class TjimCustomShape. [Ed: please note that we have changed it to ‘Jv” in the JEDI VCL edition] As you would expect, this means that we will need to add some capabilities here first, to support our later work. In fact, we will need quite a few additions, as you can see from listing 1.

TjimCustomShape = class(TGraphicControl)

    // All controls descend from this, to help with streaming and unique naming

  private

    FCanProcessMouseMsg : Boolean;

    FCaption            : TjimTextShape;

    FSelected           : Boolean;

    FWasCovered         : Boolean;

  protected

    procedure SetCaption(Value : TjimTextShape); virtual;

    procedure MouseDown(Button : TMouseButton;Shift : TShiftState;

                        X,Y : Integer); override;

    procedure MouseUp(Button : TMouseButton;Shift : TShiftState;

                      X,Y : Integer); override;

    function  GetCustomShapeAtPos(X,Y : Integer) : TjimCustomShape;

    property  CanProcessMouseMsg : Boolean read FCanProcessMouseMsg

                                          write FCanProcessMouseMsg;

    procedure SetParent(AParent : TWinControl); override;

    procedure SetSelected(Value : Boolean); virtual;

    procedure Notification(AComponent : TComponent;Operation : TOperation); override;

  public

    constructor Create(AOwner : TComponent); override;

    destructor  Destroy; override;

    procedure SetBounds(ALeft,ATop,AWidth,AHeight : Integer); override;

    procedure AlignCaption(Alignment : TAlignment);

    // Class methods to save and load all TjimCustomShape components

    // that are children of a given control. They are class methods so that an

    // instance of TjimCustomShape is not required

    class procedure SaveToFile(const FileName : string;ParentControl : TWinControl);

    class procedure LoadFromFile(const FileName : string;ParentControl : TWinControl);

    class procedure DeleteAllShapes(ParentControl : TWinControl);

    class procedure DeleteSelectedShapes(ParentControl : TWinControl);

    class procedure UnselectAllShapes(ParentControl : TWinControl);

    property Selected : Boolean read FSelected write SetSelected;

  published

    property Caption : TjimTextShape read FCaption write SetCaption;

    // Make these properties available

    property OnClick;

    property OnDblClick;

  end;

The first thing to note is that I decided (without consulting you) to move the Caption property from TjimBitmapShape to here. This purely selfish decision was because when writing the use case editor, I noticed that everything needed a caption, including connectors, and it made life a bit easier if I put the property here. This also entailed adding the AlignCaption method, along with overridden SetParent and Notification methods, and a destructor. The AlignCaption method allows you to align the caption below the component, so that the caption will be aligned with its left or right edges, or centred. The SetParent method also sets the caption’s parent. The Notification method is needed to check whether the caption is being removed. The destructor frees the caption, and checks whether the component being destroyed is at either end of any connectors. If so, the connectors are also destroyed. (You may find a circumstance where this behaviour is not appropriate, but I couldn’t think of one.) The remaining additions are to do with handling mouse messages, and performing operations on entire diagrams. Let’s consider the latter first.

The Case of the Diagram Class that Barked in the Night

What diagram class? Exactly, Watson! Why have we only created classes for different sorts of diagram elements, and no class to encapsulate a diagram? Well, my indolence and torpidity notwithstanding, it’s because there are several ways you might want to go, and I thought I’d leave the choice up to you. One way is to inherit from a control like a TPanel or TScrollBox, and add the relevant methods to control various aspects of diagrams. You might, for instance, want to use the control’s colour and font settings in some of the diagram elements. Another possibility is to separate the diagram class from the control the diagram is drawn on. In this case you will need a property to store where to do the drawing. (Make it of type TWinControl for maximum flexibility.) The diagram class will then concern itself only with operations like storing and loading diagrams from files, deleting diagram elements etc. These operations will be needed whatever you do, so I decided to make them class methods of our base class, and let you move them elsewhere if you wish. 

For those of us not familiar with them, class methods act on classes as well as objects. All Delphi objects have some of these already defined. An example is the ClassName function. The result of calling TPanel.ClassName is “TPanel”. If you have an object (Panel1, say) of type TPanel,  then calling Panel1.ClassName will give the same result. There are restrictions, of course. The identifier Self represents the class where the method is called, not an object instance. This means that you cannot reference fields, properties or normal object methods, only constructors and other class methods. The advantage is that you do not need an instance of a class to exist to call its class methods (which can be either functions or procedures, by the way).

The class procedures we will be using do exactly as their names suggest, and are simple enough to follow, so we will consider only the two most interesting (see Listing 2). Let’s look at SaveToFile first. Obviously the FileName parameter is the name of the file where will store the diagram. Less obviously, ParentControl is the control on which we have drawn the diagram we are about to save. This parameter is common to all the class procedures. The first thing we need to do is create or open the file. We will use file streams for file access for two reasons. One, I have found them to be more efficient than normal Pascal file routines, and two, because Delphi uses streams to store forms and components, and we will be cheating and letting Delphi do most of the work for us. To this end, the next thing we need is a writer object, which is something that knows how to store a component to a stream. Better still, it will store any child controls automatically. Brian Long covered using streams and readers and writers back in issues 9 and 10, and if you are on unfamiliar ground here, I recommend that you take a look at his descriptions first, because I find the Delphi help files to be a little obscure on this topic.

Once we have the writer object, life is really simple. First we need to set its Root property to the owner of all the components we will be saving. We then temporarily set the ParentControl’s name to a blank string, let the writer store the ParentControl (and therefore all its children, which will be our diagram elements), and restore the name. I blank the name because we might want to load the diagram back onto a different control than the one we stored from, and this avoids any duplicate name exceptions being raised in the LoadFromFile procedure, which we will look at now.

This is hardly any more complicated. We first clear any existing diagram by calling another class procedure, then go through the same procedure, except this time we need a reader object. Notice that the name property of the ParentControl (where the diagram is going to be drawn) is saved, so that we can restore it after reading in the blank name we stored in the file. We set the Root property of the reader object, and then do the really clever bit. You may be wondering how we are going to restore object references. What do I mean? Well, take the Caption property of our diagramming classes. When you get right down to it, it is actually a pointer to an instance of a TjimTextShape object. When we read the diagram back in, it is highly unlikely that the TjimTextShape object will be at the same memory address, so we can’t store that. What do we do? Practically nothing. Borland (oops, Inprise) have already done it for us. We need only 3 lines of code. First call the reader’s BeginReferences method, to tell it “Oi, reader! Object references on the way”. It will then keep a list of all the properties that reference objects. After reading in all our objects with the ReadComponent procedure, we call FixupReferences, and the reader will very kindly go through and assign the correct addresses everywhere. In the finally block we must call EndReferences. The Delphi help files do say that we should never need to use these routines, but hey, let’s live dangerously. There is one other very important thing that we must do to enable all this to work, and that is to tell Delphi what classes are going to be read and written. Our routine RegisterStorageClasses gets called in the initialization section of JimShape.pas to make sure that it is always executed. This routine calls Delphi’s RegisterClasses method to register all our storable class types with Delphi’s streaming system. If you derive new classes you must either add your classes to this procedure, or call RegisterClass or RegisterClasses yourself, otherwise you will get exceptions when trying to load diagrams.
That’s it. Last time I promised that loading and retrieving files would be easy, and so it is. You may need to do something more complicated in your applications, but the basics will remain the same. It is not necessary to use file streams, for instance. You can use memory streams if you wish, which might give you more storage options, like storing several diagrams in one file using OLE structured storage.

class procedure TjimCustomShape.SaveToFile(const FileName : string;

                                           ParentControl : TWinControl);

  var

    FS       : TFileStream;

    Writer   : TWriter;

    RealName : string;

begin {SaveToFile}

  FS     := TFileStream.Create(Filename,fmCreate or fmShareDenyWrite);

  Writer := TWriter.Create(FS,1024);

  try

    Writer.Root        := ParentControl.Owner;

    RealName           := ParentControl.Name;

    ParentControl.Name := '';

    Writer.WriteComponent(ParentControl);

    ParentControl.Name := RealName;

  finally

    Writer.Free;

    FS.Free;

  end;

end;  {SaveToFile}

class procedure TjimCustomShape.LoadFromFile(const FileName : string;

                                             ParentControl : TWinControl);

  var

    FS       : TFileStream;

    Reader   : TReader;

    RealName : string;

begin {LoadFromFile}

  DeleteAllShapes(ParentControl);

  FS     := TFileStream.Create(Filename,fmOpenRead or fmShareDenyWrite);

  Reader := TReader.Create(FS,1024);

  try

    // Save the parent's name, in case we are reading into a different

    // control than we saved the diagram from

    RealName    := ParentControl.Name;

    Reader.Root := ParentControl.Owner;

    Reader.BeginReferences;

    Reader.ReadComponent(ParentControl);

    Reader.FixupReferences;

    // Restore the parent's name

    ParentControl.Name := RealName;

  finally

    Reader.EndReferences;

    Reader.Free;

    FS.Free;

  end;

end;  {LoadFromFile}

procedure RegisterStorageClasses;

begin {RegisterStorageClasses}

  RegisterClasses([TjimCustomShape,

                   TjimMoveableShape,

                   TjimSizeableShape,

                   TjimConnection,

                   TjimConnector,

                   TjimSingleHeadArrow,

                   TjimBluntSingleHeadArrow,

                   TjimDoubleHeadArrow,

                   TjimBitmapShape,

                   TjimTextShape,

                   TjimStandardShape]);

end;  {RegisterStorageClasses}

Listing 2.

Hickory dickory dock

Right, what about these mouse events, then? In keeping with object oriented principles, we will add the abilities to move and size components in separate classes. I have again taken a unilateral decision to inherit sizeable components from movable ones, because it seemed unlikely that a sizeable component would not also need to be moved. Before we discuss the classes that do the real work, there are a few things that we need to add to our base class to support them. Firstly, it is important to note that because TjimCustomShape is derived from TGraphicControl, our diagramming classes can receive mouse messages, but not get the focus. So we need to fake that with our own Selected property. We will use an access method for the property (SetSelected) so we can set the caption’s Selected property in tandem. The reason for this will become obvious when we start moving things.

Secondly, we need to determine whether the control will be able to do anything with mouse messages. For instance, as they stand, the connectors do not need to process mouse messages, but they may cover (transparently) the control the user is really trying to click on. The protected property CanProcessMouseMsg is used to check whether it is necessary to pass the message on. It is set to True in the TjimCustomShape constructor, and this setting is only overridden in the TjimConnector constructor.

Lastly, we will override the MouseDown and MouseUp methods, which are called in response to the control receiving mouse messages. I won’t reproduce the code here as it is quite straightforward. In MouseDown, if the component can deal with messages itself, it brings itself to the top of the z-order (puts itself on top of other windows), sets MouseCapture to True, and calls its inherited method. MouseCapture is set so that it keeps getting mouse messages even if the mouse moves outside the control. This isn’t essential, but I found it makes controlling the moving or sizing smoother. If the control doesn’t process mouse messages, the MouseDown method of either a covered diagram element, or if none, the parent control is called. We need to convert the mouse position parameters x and y to the appropriate coordinates first, because the mouse position is measured relative to the control receiving the message. We will also set the FWasCovered field of any covered shape to True. This is used in the overridden MouseUp method. If we have transferred “focus” to a covered control, it will not receive a mouse click message when the mouse button is released (because it didn’t get a mouse down event). To enable the correct behaviour, we will simulate the receipt of a mouse click by calling the Click procedure directly.

Movin’ an’ a groovin’
We’re ready to develop our moving class. The behaviour we will implement has three parts. Firstly, clicking on a component will select it. Penultimately, holding down the shift key while we click will allow us to select several components at once. Lastly, holding down the left mouse button while moving the mouse will move the selected components. Listing 3 shows the new class. As you would expect, we are going to override the methods called as a result of mouse down, mouse move and mouse up messages. Once again, the code is pretty simple, so I will just describe it and you can follow through the code on the cover disk. 

Let’s start with the MouseDown method. We first call the inherited method, then check whether the shift key is being held down. If it is, then multiple selections are being made, otherwise only the component receiving the message is being selected, so we should unselect all others. Having done that, we call StartMove, which simply sets the Selected and Moving properties to True, and stores the current mouse position in FOrigin. We will use FOrigin to determine how far to move the component. Next, when a mouse move message is received, the component will call our newly overridden MouseMove method. It also first calls its inherited method, and then determines if the left mouse button is being held down. If so, the component is being moved, and we need to call MoveShapes. This routine takes as parameters the distances to move all selected controls in the x (left to right) and y (up and down) directions. These distances are the difference between the current mouse position, and the stored starting point in Forigin. MoveShapes scans through all the elements of our diagram looking for selected shapes. Actually it does it twice, the first time checking that all moves are valid (that is, they will remain within the bounds of the drawing surface), then, if everything’s ok, doing the actual moves. Note that because we have set the Selected property of the component’s caption (if any) to match the component, it will get moved the same amount as the component. We can also move the caption independently, of course. Finally, when the mouse button is released, the Moving property and FOrigin are reset, so that further mouse movements do not result in any control movements. To make life a little easier for end users, we will then loop through the controls looking for any shapes that are completely covered by the current one (recall that it has been brought to the top of the z-order by being selected). If we find one, then the covered shape is brought to the top, so access to it is possible.

TjimMoveableShape = class(TjimCustomShape)

  private

    FOrigin   : TPoint;

    FMoving   : Boolean;

  protected

    procedure StartMove(X,Y : Integer);

    procedure Move(DeltaX,DeltaY : Integer);

    procedure EndMove;

    function  ValidMove(DeltaX,DeltaY : Integer) : Boolean;

    procedure MoveShapes(DeltaX,DeltaY : Integer);

    procedure MouseDown(Button : TMouseButton;Shift : TShiftState;

                        X,Y : Integer); override;

    procedure MouseMove(Shift : TShiftState;X,Y : Integer); override;

    procedure MouseUp(Button : TMouseButton;Shift : TShiftState;

                      X,Y : Integer); override;

    property Moving   : Boolean read FMoving write FMoving;

  public

    constructor Create(AOwner : TComponent); override;

  end;
Listing 3.

Drink me, eat me

Now let’s implement the sizing behaviour. What we need is for sizeable controls to show little sizing rectangles when they are selected, much like Delphi’s controls do when dropped on a form. Then when the mouse gets moved over them, the cursor needs to change to one of the arrows that shows the direction in which the resizing will occur if that rectangle is moved. If the left mouse button is held down over a sizing rectangle and the mouse is moved, then the appropriate resizing will be done. Listing 4 shows the class declarations we will use. As in the moving class, we need to override the mouse methods. However, there are a few ancillary bits and pieces we need. The main one is the TjimSizingMode class, which we will use to keep track of what sort of resizing we are doing. Note that we have the 8 major directions, and a special smNone mode, to indicate that no sizing is currently necessary. We also need to override the Paint method to draw the sizing rectangles, and SetBounds, to make sure that the control never gets smaller than one of those rectangles. SetBounds also ensures that the control cannot be sized beyond the top or left of the drawing surface.

There are a few properties that we will use. FSizeOrigin serves a similar purpose to FOrigin in keeping track of the amount of sizing movement required. SizeRectHeight and SizeRectWidth control the dimensions of the sizing rectangles. MinHeight and MinWidth are set to the smallest size allowed for the control. For the TjimSizableShape, this will be the size of one sizing rectangle. In descendant classes, this might be larger. For instance, in TjimTextShape, the smallest size will be a rectangle that encloses all the text. The last property, FSizingMode, keeps track of the type of sizing we are doing. The main helper function is GetSizeRect, which returns (in coordinates relative to the sizeable control) the sizing rectangle corresponding to the mode passed to it.

TjimSizingMode = (smTopLeft,smTop,smTopRight,smLeft,smRight,

                    smBottomLeft,smBottom,smBottomRight,smNone);

  TjimSizeableShape = class(TjimMoveableShape)

  private

    FSizingMode     : TjimSizingMode;

    FSizeOrigin     : TPoint;

    FSizeRectHeight : Integer;

    FSizeRectWidth  : Integer;

    FMinHeight      : Integer;

    FMinWidth       : Integer;

  protected

    procedure SetSelected(Value : Boolean); override;

    procedure Paint; override;

    procedure DrawSizingRects;

    function  GetSizeRect(SizeRectType : TjimSizingMode) : TRect;

    procedure CheckForSizeRects(X,Y : Integer);

    procedure ResizeControl(X,Y : Integer);

    procedure MouseDown(Button : TMouseButton;Shift : TShiftState;

                        X,Y : Integer); override;

    procedure MouseMove(Shift : TShiftState;X,Y : Integer); override;

    procedure MouseUp(Button : TMouseButton;Shift : TShiftState;

                      X,Y : Integer); override;

    property  SizingMode     : TjimSizingMode read FSizingMode write FSizingMode;

    property  SizeRectHeight : Integer read FSizeRectHeight write FSizeRectHeight;

    property  SizeRectWidth  : Integer read FSizeRectWidth write FSizeRectWidth;

    property  MinHeight      : Integer read FMinHeight write FMinHeight;

    property  MinWidth       : Integer read FMinWidth write FMinWidth;

  public

    constructor Create(AOwner : TComponent); override;

    procedure SetBounds(ALeft,ATop,AWidth,AHeight : Integer); override;

  end;
Listing 4.

The most important methods, though, are shown in Listing 5. Taking them in order, MouseDown first checks to see whether we should be sizing the control. If the sizing mode is smNone, or a button other than the left one is being used, or the shift key is being held down, then we are doing something other than sizing the component, and we need to call the inherited MouseDown method. Otherwise we will start resizing by making this the only selected control, and setting FsizeOrigin to the current mouse position. 

MouseMove needs to do one of three things depending on the circumstances. Firstly, if the control is being moved, call the inherited MouseMove method (which will be the one in TjimMoveableShape). Otherwise, if the left mouse button is being held down, and the sizing mode has been set, we will resize the control. Finally, if neither of these cases applies, we need to check whether the cursor is over one of the sizing rectangles. If it is then the cursor needs to be set appropriately (in CheckForSizeRects). The procedure that actually resizes the control is ResizeControl (good with names, aren’t I?), which is quite a large routine, but only because of the number of different sizing modes that need to be handled. You won’t have any trouble following the code, so we won’t go through it now.

procedure TjimSizeableShape.MouseDown(Button : TMouseButton;Shift : TShiftState;

                                      X,Y : Integer);

begin {MouseDown}

  if (FSizingMode = smNone) or

     (Button <> mbLeft) or

     (ssShift in Shift) then begin

    // Do moving instead of sizing

    FSizingMode := smNone;

    inherited MouseDown(Button,Shift,X,Y);

    Exit;

  end;

  // If sizing then make this the only selected control

  UnselectAllShapes(Parent);

  BringToFront;

  FSelected   := True;

  FSizeOrigin := Point(X,Y);

end;  {MouseDown}

procedure TjimSizeableShape.MouseMove(Shift : TShiftState;X,Y : Integer);

begin {MouseMove}

  if Moving then begin

    inherited MouseMove(Shift,X,Y);

  end else if (FSizingMode <> smNone) and (ssLeft in Shift) then begin

    ResizeControl(X,Y);

  end else begin

    // Check if over a sizing rectangle

    CheckForSizeRects(X,Y);

  end;

end;  {MouseMove}

procedure TjimSizeableShape.MouseUp(Button : TMouseButton;Shift : TShiftState;

                                    X,Y : Integer);

begin {MouseUp}

  if Button = mbLeft then begin

    FSizingMode := smNone;

  end;

  inherited MouseUp(Button,Shift,X,Y);

end;  {MouseUp}

Listing 5.

Lipstick and rouge

Now that we can move and size diagram elements, we need to make some changes to the inheritance hierarchy from last month, to add these new capabilities. We will also need a couple of new classes for our example application, and I have made some cosmetic changes to the existing classes. I will just list the changes and let you examine the source for yourself. I also have to admit to having found a small bug in some routines. We will also make a performance enhancing change to the TjimConnector class, and then we’ll start to build our use case editor.

The inheritance hierarchy changes are minor. Firstly, we will make TjimBitmapShape a descendant of TjimMoveableShape, so that it can be moved but not resized. You could easily change this, but you will probably need to implement properties (and override the Paint method) to make the control work more like a TImage. We will also need to change the Paint method so that it draws and removes a focus rectangle, depending on whether the component is selected. The simplest way to achieve this is to always draw the focus rectangle, but use different pen modes. Using pmNop will ensure the pen is the same colour as the background, while using pmNot will use the inverse colour. Secondly, TjimTextShape will become both movable and sizeable when we change its parent class to TjimSizeableShape. 

We will need a new type of diagram element to draw use case diagrams, so there is a new (sizeable) class TjimStandardShape, which will allow us to draw any of the shapes defined by Delphi’s TShapeType class (rectangles, squares, rounded rectangles, rounded squares, ellipses and circles). There is also a need for two new connector types. One has an arrowhead at both ends (TjimDoubleHeadArrow). The other has a small straight section of line at the start end of the connector (TjimBluntSingleHeadArrow). This latter one is purely for looks. Last month’s article described the procedure for deriving new diagram element classes.

The cosmetic changes include adding a Font property to TjimTextShape. We will follow the advice given in Danny Thorpe’s excellent book “Delphi Component Design” which tells us how to do exactly this (on pp 59 to 61). The main point to note is the new private FFont property, which has an instance of TFont assigned to it in the constructor. This allows us to assign a private font change notification procedure (the FontChanged method) to the FFont object. The change notification method ensures the control gets redrawn, and possibly resized, when the font changes. Obviously, we will change the Paint method to set the canvas font before drawing the text. Because we have created a TFont object, we need to override the destructor to ensure it is destroyed. It would also be nice to be able to have multiline captions. This ability is added by the RefreshText method, which basically determines the number of lines in a caption by counting the carriage returns in the Text property. Remember that earlier on we mentioned using MinWidth and MinHeight to ensure the control could not be sized smaller than the text? Well, this is where that is done. RefreshText finally calls SetBounds to do the actual work of resizing, so it replaces most of the calls to SetBounds in the text shape class. You may wish to get clever and implement automatic word wrapping, or use a TStringList instead of a string to hold the text.

I made a slight error last month, in the LeftMost, RightMost, TopMost and BottomMost methods of TjimConnection. They have been corrected in the code for this article. I had used widths and heights of the terminator rectangle the wrong way around in places. Mea culpa (Latin for “I’m an idiot”).

The most complicated changes are saved for the connector class. The simplest addition is the ability to specify the line colour. All we need is a property in which to store it, and to change the Paint method slightly to specify the pen colour before we do any drawing. The remaining changes are in connection with a new property that TjimConnector inherits from TjimCustomShape : the Caption.

As I said earlier, use case diagrams need connectors with captions, which was the prime motivation for moving the property up the inheritance hierarchy. It does mean a bit of extra work here as well. For a start, the earlier strategy of moving the caption the same amount as the component it belongs to won’t work here. What we will do instead is move it in relation to the movement of the midpoint of the connector. As before, we need to track this movement, which we will do with FMidPoint. The MoveCaption method performs the actual moving. It was at this point that I ran into a performance problem. Using SetBounds to move the caption proved very slow when several connectors were being resized at once (for instance, when moving a shape which had several connectors attached to it). I did find a quicker way of resizing a control, which paradoxically requires more work. However, this new approach is used both in MoveCaption and SetBoundingRect (which you will remember sets the size of the connector). First invalidate the control, then call UpdateBoundsRect to resize it (in the case of the connector) or move it (in the case of the caption). The downside is that UpdateBoundsRect is not a virtual method, and cannot be overridden, so we will normally still need to perform our sizing checks in the SetBounds method of most of our classes. In these two special cases, it is safe to skip that step, but the technique cannot be used as a general replacement for SetBounds. The remaining changes to the connector class are pretty much just rearrangements of the existing code, or insertions of calls to MoveCaption at appropriate points.

The last point I would like to make is that as a consequence of the inheritance structure as we have defined it, captions are themselves able to have captions. I’m in two minds as to whether this is a good thing, and we won’t make use of it, but you might find it helpful. So now we’re done, and ready to move on to this month’s example application.

Use it or lose it

Before we start building our use case editor, a short discussion of use cases is in order. It will be very brief, but there is plenty of information out there. Programming wizards who already know this stuff may wish to skip this section. Proto-wizards should know that use cases, originally developed by Ivar Jacobsen, are now used in many object oriented methodologies. Perhaps the most important of these is the Rational Unified Process, which merges features from the best of the older methods. As its notation, the Unified Process uses the Unified Modelling Language (UML), which has also been adopted as a standard by the Object Management Group. One of the many diagram types that the UML defines is that of use case diagrams, and our example application will be based on this notation. For simplicity, not all the features will be implemented, but you will be able to add them yourself if you wish. There is a great deal of information on both UML and the Unified Process on Rational’s web site at www.rational.com. Use cases are usually one of the first deliverables from a project, as they are used when eliciting the requirements, and are then used in other phases, like designing the class hierarchy, and developing test cases.

Enough waffle, what exactly are use cases? Simply put, they describe what a system should do, from the point of view of users of the system. Here users may be actual people, pieces of hardware, or even other computer systems. In use-case modelling terms, a user is called an actor. It is important to note that an actor is usually a class of users, rather than a particular person (eg “Sales Person” rather than “my mate Fred in Sales”), and that often the same person will perform the role of several actors. An actor is denoted by a stick figure. 

A use case is a set of actions that the system performs to yield an observable result to an actor. Sounds a bit obscure, doesn’t it? We’ll get to an example in a minute and perhaps it will make things clearer. An ellipse denotes a use case. Each use case should also have a description, where the required behaviour is set out. This can be text, other types of diagrams, or a combination of both. Both actors and use cases have names. We will only implement the names, because the point of the exercise is the diagramming capabilities.

There are also associations in a use case diagram. One sort is that between actors and use cases, to show the communication between them. This is normally two-way, so we will use a double-headed arrow in our use case editor. The other sorts are between use cases, and are extends, which is similar to inheritance, and uses, where one use case makes use of the behaviour of another. These are indicated by single headed arrow, pointing at the use case being extended or used, with the caption (called a stereotype in UML) <<extends>> or <<uses>> to indicate the association type. We will not implement the third relationship between use cases, that of grouping, which is a way of bundling up related use cases. There is also an inheritance relationship between actors that we will not put in our editor either.

Figure 1 shows an example of a use case diagram, with both extends and uses relationships. Hopefully it is fairly self-explanatory. It is a simple view of an automatic teller machine (ATM) system. There is only one actor, the bank customer. The customer can deposit or withdraw cash, or request the balance of their account. In all 3 cases the customer must first insert their ATM card, enter their PIN, and choose an account, which we will call the “Use ATM” use case. So the three actions the customer can perform, can be considered special cases of this more general one, hence the use of the extends relation. Depositing and withdrawing cash will both change the customer’s account balance, hence the uses relation with the “Update Balance” use case. It should be clear that if an actor or use case is not somehow related to another, it has no place on a use case diagram. We won’t check for well-formed diagrams, but it might be a good idea in a more complete editor. That’s really as much detail as we can go into here.  Recommendations for further reading are in the bibliography.
[image: image1.png]causesny

Customer .H

Waiing





Figure 1.

Making an example of ourselves

The use case editor program is in many ways similar to last month’s web mapper example. We still need to construct and connect shapes, but this time under control of the user. To this end we will use a toolbar with buttons for the required shapes and types of connectors. The user will be able to click on, say, the actor button, then on the drawing surface, and the actor shape will be drawn with its upper left corner at the mouse click position. The actor and its caption can be moved around as described earlier. Double clicking on a caption will bring up a dialog to edit the text. Clicking on a connector tool button will put the editor into “connection mode”, where the user must select two shapes. We will check that the right sort of shapes are being connected, that is, only use cases can connected by uses and extends relationships, and only an actor and a use case by the communication association. We will do this by using a finite state machine. Clicking on a tool button will put the program into one of the states defined by TjimNextAction. Clicking on the drawing surface (ScrollBox1) or a shape will result in a shape being added, a connection made, or an exception raised, depending on the circumstances. ScrollBox1MouseDown will handle clicks on the drawing surface, and ShapeClick will handle clicks on any shapes, because we will assign it to the OnClick handler of each shape we create (except connections). We will enable hints, and put a description of the next required action in the status bar. All this code is on the disk, and you will see that it is quite small, with little work needing to be done to implement a quite functional program.

Bedebedebdebethat’s all folks

That completes the description of our diagramming classes. It was a bit of a slog, but hopefully it will have been useful. There are a host of extensions that we could have added, including drawing anti-aliased lines, or using the bezier curve routines to draw curved lines. Possibly we could have defined a background colour for TjimStandardShape and TjimTextShape. We will almost certainly want to print diagrams. I use ReportPrinterPro for all my printing needs, by the way, because I wouldn’t write Windows printing code for any money. We could even have made our diagram editor an OLE server, so diagrams could be included in other documents. I would be interested to hear of any uses to which you put these classes, or better still, any improvements you make. Have fun.

